*  ENCUESTA DE EMPLEO
*  SINTAXIS EN SPSS   PARA: 
*                                  Cálculo del Ingreso del p20 (variable INGRL)
*                                  Cálculo de la Condición de Actividad (variable CONDACT)
*                                  Cálculo de la sectorización de la PEA (variable PEAMSIU)
*-------------------------------------------------------------------------------------------------------------------------------------------.

*CALCULO DEL INGRESO.

compute ingrl = 0.
compute ingrlx =0.

if (p50=1 and p63=999999 and p64a=2) ingrlx=999999.
if (p50=1 and p63=999999 and p64a=1 and p64b=999999) ingrlx=999999.
if (p50=1 and p66=999999 and p67=999999 and p68a=2) ingrlx=999999.
if (p50=1 and p66=999999 and p67=999999 and p68a=1 and p68b=999999) ingrlx=999999.

if (p50=2 and p63=999999 and p64a=2 and p69=999999 and p70b=999999) ingrlx=999999.
if (p50=2 and p63=999999 and p64a=1 and p64b=999999 and p69=999999 and p70b=999999) ingrlx=999999.
if (p50=2 and p66=999999 and p67=999999 and p68a=2 and p69=999999 and p70b=999999) ingrlx=999999.
if (p50=2 and p66=999999 and p67=999999 and p68a=1 and p68b=999999 and p69=999999 and p70b=999999) ingrlx=999999.
if (p50=2 and p63=999999 and p64a=2 and p69=999999 and p70a=2) ingrlx=999999.
if (p50=2 and p63=999999 and p64a=1 and p64b=999999 and p69=999999 and p70a=2) ingrlx=999999.
if (p50=2 and p66=999999 and p67=999999 and p68a=2 and p69=999999 and p70a=2) ingrlx=999999.
if (p50=2 and p66=999999 and p67=999999 and p68a=1 and p68b=999999 and p69=999999 and p70a=2) ingrlx=999999.
IF (P63=999999) ingrlx=999999.
IF (P66=999999) ingrlx=999999.


*-------------------------------------------------------------------.
compute ingr=0.
if (p63<999999) ingr =(ingr + p63).
if (p64b<999999) ingr =(ingr + p64b).
if (p65<999999) ingr = (ingr - p65).
if (p66<999999) ingr =(ingr + p66).
if (p67<999999) ingr = (ingr + p67).
if (p68b<999999) ingr =(ingr + p68b).

**  PERSONAS QUE NO TIENEN INGRESOS DEL p20 **.
DO IF (missing(p63) and missing(p64b) and missing(p65) and missing(p66) and missing(p67) and missing(p68b)).
     RECODE
         ingr (0=sysmis)
     .
END IF.

** PERSONAS QUE NO INFORMAN INGRESOS COMO PATRONOS o CTA.PROPIA o COMO ASALARIADOS.

IF (P63=999999) ingr=999999.
IF (P66=999999) ingr=999999.

*-----------------------------------------------------------------.
compute ingrs=0.
if (p69<999999) ingrs =(ingrs + p69).
if (p70b<999999) ingrs =(ingrs + p70b).
execute.

**  PERSONAS QUE NO TIENEN INGRESOS DEL p20 **.
DO IF (missing(p69) and missing(p70b)).
     RECODE
         ingrs (0=sysmis)
     .
END IF.

DO IF (p69=999999 and p70b=999999).
      recode
          ingrs (0=999999).
END IF.

DO IF (missing(p69) and p70b=999999).
      recode
          ingrs (0=999999).
END IF.

*--------------------------------------------------------------------------------.
compute ingrl=0.
*-----ojo lo que sigue---.
if (ingr<0 and ingrs<999999) ingrl=ingrl+ingrs.
if (ingr>=0 and ingr<999999 and ingrs<999999) ingrl=ingrl+ingr+ingrs.

if (missing(ingr) and ingrs<999999) ingrl=ingrl+ingrs.
if (missing(ingrs) and ingr>=0 and ingr<999999) ingrl=ingrl+ingr.
if (ingr<0 and missing(ingrs)) ingrl=-1.
if (ingr=999999 and missing(ingrs)) ingrl=999999.
if (ingr=999999 and ingrs>=0 and ingrs<999999) ingrl=999999.

DO IF (missing(ingr) and missing(ingrs)).
     recode ingrl (0=sysmis).
END IF.


VALUE LABEL
  ingrl   -1 'Gasta mas de lo que gana'
           999999 'No informa'
.


*CALCULO DE LA VARIABLE CONDACT .

compute salmin = 340.

*{empleada domestica (cambia de 120 a 170 desde 02/2008)}.
if (p40=9500 and p42=10 and (p41=9131 or p41=9133)) salmin = 340.
if (p40=9500 and p42=6 and p41=9133) salmin = 340.

*{Empleados Privados (cambia de 170 a 200 desde 02/2008)}.
if (p42>=2 and p42<=4) salmin = 340.

*{Empleados Publicos se cambia de 350 a 445 desde 07/2008}.
if (p42=1) salmin = 527.
execute.

compute hortrah = 0.
if (p51a<>999)  hortrah = (hortrah + p51a).
if (p51b<>999)  hortrah = (hortrah + p51b).
if (p51c<>999)  hortrah = (hortrah + p51c).
execute.

*{OCUPADOS}.
compute condact = 0.
compute ocupado = 0.
if (p20=1) ocupado = 1.
if (p20=2 and p21>=1 and p21<12) ocupado = 1.
if (p20=2 and p21=12 and p22=1) ocupado = 1.

*{OCUPADOS PLENOS}.
Do if (ocupado=1 and condact=0).
   if (p24>=40 and p24<999 and ingrl>=salmin and p27=4 and ingrl<999999) condact = 1.
   if (p24<40 and ingrl>=salmin and p27=4 and ingrl<999999) condact = 1. 
   if (p24<40 and ingrl>=salmin and p27<4 and (p28=2 or p30=7) and ingrl<999999) condact = 1.
   if (p24<40 and ingrl>=salmin and ingrl<999999 and p25=9) condact=1.
END IF.
Do if (ocupado=1 and condact=0).
   if (hortrah>=40 and hortrah<999 and ingrl>=salmin and p27=4 and ingrl<999999) condact = 1.
   if (hortrah<40 and ingrl>=salmin and p27=4 and ingrl<999999) condact = 1. 
   if (hortrah<40 and ingrl>=salmin and p27<4 and (p28=2 or p30=7) and ingrl<999999) condact = 1. 
   if (hortrah<40 and ingrl>=salmin and ingrl<999999 and p25=9) condact=1.
END IF.

*{SUBEMPLEADOS VISIBLES}.
Do if (ocupado=1 and condact=0).
   if (p24<40 and p27<4 and p28=1) condact = 2.
   if (hortrah<40 and p27<4 and p28=1) condact = 2.
END IF.

*{OTRAS FORMAS DE SUBEMPLEO}.
if (ocupado=1 and condact=0 and ingrlx<999999 and p24<999) condact = 3.      

*{DESOCUPADOS}.
compute desocup=0.
Do if (ocupado=0).
   if (p20=2 and p21=12 and p22=2 and p32<11) desocup=1.
   if (p20=2 and p21=12 and p22=2 and p32=11 and p34<8 and p35=1) desocup=1.
END IF.


*{DESEMPLEO OCULTO}.
Do if (desocup=1 and condact=0).
   if (p34<8) condact = 6.   
END IF.

*{DESEMPLEO ABIERTO}.
if (desocup=1 and condact=0 and p32<11) condact=5.
if (desocup=1 and condact=0) condact=5.

*{INACTIVOS}.
if (p34>=8 or p35=2) condact = 7.

*{MENORES DE p03}.
if (p03<15) condact=8.

EXECUTE.

* PROC PEAMSIU.

compute peamsiu = 0.
Do if (condact<7).
   if (p47a=2) peamsiu = 1.
   if (p47a=1 and p47b>10) peamsiu = 1.
   if (p47a=1 and p47b<=10 and p49=1 and p48=1) peamsiu = 1.
   if (p47a=1 and p47b<=10 and (p48=2 or p48=3 or p49=2)) peamsiu = 2.
   IF (p47a=1 AND p47b<=10 AND (P48=4 OR P49=3)) PEAMSIU=5.
   if (p40=9500 and (p41=9131 or p41=9133 or p41=9152)) peamsiu=3.
   if (p42=10) peamsiu=3.
   if (condact=5 or condact=6) peamsiu=4.
   if (peamsiu=0) peamsiu=5.
END IF.

if (p03<15) condact=8.
if (p03<15) peamsiu=0.

VALUE LABEL
CONDACT 
     0 "Ocupado No Clasificados"
     1 "Ocupación Plena"
     2 "Subempleo Visible"
     3 "Otra forma de Subempleo"
     5 "Desempleo Abierto"
     6 "Desempleo Oculto"
     7 "Inactividad"
     8 "Menores de 15 años"
/PEAMSIU 
     0 "Inactivos o Menores de 15 años"
     1 "Sector Formal"
     2 "Sector Informal"
     3 "Servicio Domèstico"
     4 "Desocupados"
     5 "Ocupados No Clasificados"
.

VAR LABEL
INGRL    "Ingreso del p20"
/CONDACT  "Condiciòn de Actividad"
/PEAMSIU  "Sectorizaciòn de la PEA"
.

EXECUTE.